home
***
CD-ROM
|
disk
|
FTP
|
other
***
search
/
64'er
/
64ER_CD.iso
/
86xx
/
8603.d64
/
view picture
(
.txt
)
< prev
Wrap
Commodore BASIC
|
1995-03-30
|
2KB
|
39 lines
0 REM **************************
1 REM * VIEW PICTURE *
2 REM * ------------ *
3 REM * *
4 REM * WRITTEN 1985 *
5 REM * BY *
6 REM * *
7 REM * R.EICHENBERGER *
8 REM * *
9 REM **************************
10 :
11 POKE53280,11:POKE53281,12:REM BILDSCHIRMFARBEN AENDERN
15 FORT=0TO27:READA:POKE828+T,A:NEXT:REM EINLESEN DES MASCH.PRG NACH $033C
20 PRINT"[147][144][169] [223][146]";
30 PRINT" VIEW PIC (8192) [146]";
40 PRINT"[223] [146][169]";:REM BILDSCHIRMMASKE
50 PRINT"[151]FILENAME: ";:OPEN1,0:INPUT#1,NA$:CLOSE1:REM EINGABE DES NAMENS
60 IFNA$=""THENGOTO120:REM WENN KEIN NAME, DANN BILD ZEIGEN
100 PRINT"[147]L[207]"+CHR$(34)+NA$+CHR$(34)+",8,1":PRINT"G[207]120"
110 POKE631,19:POKE632,13:POKE633,13:POKE198,3:END:REM LADEN DES PRG'S
120 PRINT"[147]":V=53248:REM BILDSCHIRM LOESCHEN
130 POKEV+17,PEEK(V+17) OR (8+3)*16:REM GRAFIK EINSCHALTEN
140 POKEV+22,PEEK(V+22)AND255-16:REM MULTICOLOR AUSSCHALTEN
150 POKEV+24,PEEK(V+24)OR8:REM GRAFIK BEI $2000
155 SYS828:REM MASCHINEN-PRG STARTEN (FARBEN VON $4000 NACH $0400
160 GETA$:IFA$=""THEN160:REM WARTE AUF TASTE
161 PRINT"[147]":REM BILDSCHIRM LOESCHEN
170 POKEV+17,PEEK(V+17)AND255-6*16:REM GRAFIK AUSSCHALTEN
180 POKEV+22,PEEK(V+22)AND255-1*16:REM MULTICOLOR AUSSCHALTEN
190 POKEV+24,PEEK(V+24)AND255-8:REM GRAFIK WIEDER BEI $1000
200 INPUT"[147]NOCH EIN BILD:[160][J/N]";A$
210 IFA$<>"J"THENEND
220 GOTO20:REM NOCH EIN BILD, DANN ZUR ZEILE 20
225 :
226 REM *** MASCHINENPRG FUER FARBE
227 :
230 DATA162,0,160,64,134,95,132,96,162,232,160,67,134,90,132,91,162,232,160
240 DATA7,134,88,132,89,32,191,163,96